**Actuals\_IncomeStatementRunningTotal =**

VAR CurrentHeaderOrder = MAX('Income Statement Rows'[Order])

RETURN

CALCULATE([Total Actuals], REMOVEFILTERS('Income Statement Rows'),'Income Statement Rows'[Order]<CurrentHeaderOrder)

**Actuals\_IncomeStatementCustomCalculation =**

VAR CurrentCalculationName = SELECTEDVALUE('Income Statement Rows'[Header])

RETURN

SWITCH(CurrentCalculationName,

            "Gross Margin",[Gross Margin Actuals],

            "Net Income Margin",[Net Margin Actuals],

            BLANK()

)

**Actuals\_IncomeStatement =**

VAR CurrentCalcType = SELECTEDVALUE('Income Statement Rows'[CalcType])

RETURN

SWITCH(CurrentCalcType,

            1,[Total Actuals],

            2,[Actuals\_IncomeStatementRunningTotal],

            3,[Actuals\_IncomeStatementCustomCalculation],

            [Total Actuals]

)

**Format String Default** = "$#,0;(\$#,0);\$#,0"

**IncomeStatementFormatString =**

VAR IsPercentageFormat = HASONEVALUE('Income Statement Rows'[Header]) && SELECTEDVALUE('Income Statement Rows'[Format]) = "Percentage"

VAR OneOrgSelected = HASONEVALUE(Organisations[Organization])

VAR SelectedCurrencyString = SELECTEDVALUE(Organisations[Currency Code Format String])

RETURN

SWITCH(

TRUE(),

IsPercentageFormat, "0.00%",

OneOrgSelected, SelectedCurrencyString,

[Format String Default]

)

**Revenue Actuals =**

CALCULATE([Total Actuals],'Chart of Accounts'[HeaderAssignment]="Revenue")

**Gross Margin Actuals =**

VAR Revenue = CALCULATE([Revenue Actuals],REMOVEFILTERS('Income Statement Rows'))

VAR CostOfSales = CALCULATE([Total Actuals], 'Chart of Accounts'[HeaderAssignment]="Cost of Sales",REMOVEFILTERS('Income Statement Rows'))

RETURN

DIVIDE(Revenue + CostOfSales,Revenue)

**Net Margin Actuals =**

VAR NetIncome = CALCULATE([Total Actuals],REMOVEFILTERS('Income Statement Rows'))

VAR Revenue = CALCULATE([Revenue Actuals],REMOVEFILTERS('Income Statement Rows'))

RETURN

DIVIDE(NetIncome,Revenue)

**Revenue Prior Year** =

CALCULATE([Revenue Actuals],SAMEPERIODLASTYEAR(Dates[Date]))

**Gross Margin Prior Year** =

CALCULATE([Gross Margin Actuals],SAMEPERIODLASTYEAR(Dates[Date]))

**Net Margin Prior Year** =

CALCULATE([Net Margin Actuals],SAMEPERIODLASTYEAR(Dates[Date]))